复制内容到剪贴板

代码:

Y:=(HIGH+LOW)/2;
BLUE:=SMA(Y,13,1);
RED:=SMA(Y,8,1);
GREEN:=SMA(Y,5,1);
B2:=REF(BLUE,8);
R2:=REF(RED,5);
G2:=REF(GREEN,3);
KU1:=IF(HIGH=HHV(HIGH,3),1,0);
KD1:=IF(LOW=LLV(LOW,3),1,0);
UL:=IF(REF(KU1,2)=1 AND REF(KU1,1)=0 AND KU1=0,REF(HIGH,2),REF(HIGH,2+BARSLAST(REF(KU1,2)=1 AND REF(KU1,1)=0 AND KU1=0)));
DL:=IF(REF(KD1,2)=1 AND REF(KD1,1)=0 AND KD1=0,REF(LOW,2),REF(LOW,2+BARSLAST(REF(KD1,2)=1 AND REF(KD1,1)=0 AND KD1=0)));
KU:=IF(CLOSE>B2 AND CLOSE>R2 AND CLOSE>G2,1,0);
KD:=IF(CLOSE<B2 AND CLOSE<R2 AND CLOSE<G2,-1,0);
KK:=IF(BARSLAST(KU=1 AND REF(KU,1)=0)<BARSLAST(KD=-1 AND REF(KD,1)=0),1,-1);
AO:=MA(Y,5)-MA(Y,34);
AC:=AO-MA(AO,5);
AC1:=REF(AC,1);
AO1:=REF(AO,1);
AO转:(170*MA(Y,5)-170*MA(Y,34)+165*MA(Y,33)-136*MA(Y,4))/29,LINETHICK0;
AO零:(165*MA(Y,33)-136*MA(Y,4))/29,LINETHICK0;
AC转:(5*34*5*AO-5*34*5*MA(AO,5)+5*34*4*MA(AO,4)+5*4*33*MA(Y,33)-4*34*4*MA(Y,4))/116,LINETHICK0;
AC零:(5*34*MA(AO,4)-34*4*MA(Y,4)+5*33*MA(Y,33))/29,LINETHICK0;
KAC:=IF(AC>AC1 AND AO>AO1,1,0);
KAO:=IF(AC<AC1 AND AO<AO1,-1,0);
蓝:SMA(Y,13,1),SHIFT8,colorFF0000;
红:SMA(Y,8,1),SHIFT5,colorFF;
绿:SMA(Y,5,1),SHIFT3,colorFF00;
上碎型:IF(HIGH>=R2,UL,REF(UL,BARSLAST(HIGH>R2))),LINETHICK0,colorFF00FF;
下碎型:IF(LOW<=R2,DL,REF(DL,BARSLAST(LOW<=R2))),LINETHICK0,colorFFFF;
STICKLINE(BARSLAST(ABS(上碎型-REF(上碎型,1)))<BARSLAST(CLOSE>上碎型 AND REF(CLOSE,1)<REF(上碎型,1)),上碎型,上碎型,3,1),colorFF00FF;
STICKLINE(BARSLAST(ABS(下碎型-REF(下碎型,1)))<BARSLAST(CLOSE<下碎型 AND REF(CLOSE,1)>REF(下碎型,1)),下碎型,下碎型,3,1),colorFFFF;
OL:=(170*MA(Y,5)-170*MA(Y,34)+165*MA(Y,33)-136*MA(Y,4))/29;
CL:=(165*MA(Y,33)-136*MA(Y,4)+170*(4*MA(AO,4)+5*(REF(AO,4)-MA(REF(AO,4),5)))/4)/29;
H1:=REF(HIGH,4);
H2:=REF(HIGH,3);
H3:=REF(HIGH,2);
H4:=REF(HIGH,1);
H5:=HIGH;
L1:=REF(LOW,4);
L2:=REF(LOW,3);
L3:=REF(LOW,2);
L4:=REF(LOW,1);
L5:=LOW;
∥:=H3>H2 AND H3>H1 AND H3>H4 AND H3>H5;
∥FRACTAL:=IF(∥,1,0);
∥VAR1:=BACKSET(∥FRACTAL,3);
∥VAR2:=FILTER(∥VAR1,2);
∥VAR3:=BACKSET(∥FRACTAL,5);
∣:=L3<L2 AND L3<L1 AND L3<L4 AND L3<L5;
∣FRACTAL:=IF(∣,1,0);
∣VAR1:=BACKSET(∣FRACTAL,3);
∣VAR2:=FILTER(∣VAR1,2);
∣VAR3:=BACKSET(∣FRACTAL,5);
DRAWICON(∥VAR2,HIGH*1.001,'S14');
DRAWICON(∣VAR2,LOW,'S14');
DRAWICON(CLOSE>上碎型 AND REF(CLOSE,1)<REF(上碎型,1),HIGH*1.015,4);
DRAWICON(CLOSE<下碎型 AND REF(CLOSE,1)>REF(下碎型,1),LOW*0.99,5);
DRAWICON(KU=1 AND REF(KU,1)=0 AND CLOSE<0,LOW,4);
DRAWICON(KD=-1 AND REF(KD,1)=0 AND CLOSE<0,HIGH*1.01,5);
DRAWICON(KU=0 AND REF(KU,1)=1 AND CLOSE<0,HIGH*1.01,7);
DRAWICON(KD=0 AND REF(KD,1)=-1 AND CLOSE<0,LOW,6);
STICKLINE(KAC=1 AND CLOSE>=OPEN,OPEN,CLOSE,8,1),colorFF;
STICKLINE(KAO=-1 AND CLOSE>=OPEN,OPEN,CLOSE,8,1),colorFF00;
STICKLINE(KAO=0 AND KAC=0 AND CLOSE>=OPEN,OPEN,CLOSE,8,1),color808080;
STICKLINE(CLOSE>=OPEN,HIGH,CLOSE,0.4,1),colorFF;
STICKLINE(CLOSE>=OPEN,OPEN,LOW,0.4,1),colorFF;
STICKLINE(KAC=1 AND CLOSE<OPEN,OPEN,CLOSE,8,0),colorFF;
STICKLINE(KAO=-1 AND CLOSE<OPEN,OPEN,CLOSE,8,0),colorFF00;
STICKLINE(KAO=0 AND KAC=0 AND CLOSE<OPEN,OPEN,CLOSE,8,0),color808080;
STICKLINE(OPEN>CLOSE,HIGH,OPEN,0.4,1),colorFFFF00;
STICKLINE(OPEN>CLOSE,CLOSE,LOW,0.4,1),colorFFFF00;
DU0:=CROSS(AO,0);
UD0:=CROSS(0,AO);
TDU0:=BARSLAST(DU0);
TUD0:=BARSLAST(UD0);
DU3:=REF(DU0,1);
UD3:=REF(UD0,1);
TDU3:=BARSLAST(DU3);
TUD3:=BARSLAST(UD3);
UDGLINE:IF(TDU3<TUD3,REF(HHV(HIGH,2),TDU3),REF(LLV(LOW,2),TUD3)),colorFFD400;
JDU0:=REF(CLOSE,1)<=REF(UDGLINE,1) AND CLOSE>UDGLINE AND TDU0<TUD0;
JUD0:=REF(CLOSE,1)>=REF(UDGLINE,1) AND CLOSE<UDGLINE AND TUD0<TDU0;
JDU1:=JDU0 AND COUNT(JDU0,TDU0)=1;
JUD1:=JUD0 AND COUNT(JUD0,TUD0)=1;
JDU2:=JDU1 AND REF(BARSLAST(JUD1),1)<REF(BARSLAST(JDU1),1);
JUD2:=JUD1 AND REF(BARSLAST(JUD1),1)>REF(BARSLAST(JDU1),1);
JDU3:=JDU1 AND REF(BARSLAST(JUD1),1)>REF(BARSLAST(JDU1),1);
JUD3:=JUD1 AND REF(BARSLAST(JUD1),1)<REF(BARSLAST(JDU1),1);
DRAWTEXT(JDU2,LOW*0.98,'\n空\n转\n多'),ALIGN4;
DRAWTEXT(JUD2,HIGH*1.03,'\n多\n转\n空'),ALIGN5;
DRAWTEXT(JDU3,LOW*0.98,'\n多\n续\n多'),ALIGN4;
DRAWTEXT(JUD3,HIGH*1.03,'\n空\n续\n空'),ALIGN5;
BSLINE:=IF(BARSLAST(JDU2)<BARSLAST(JUD2),IF(REF(CROSS(0,AC),1) OR REF(CROSS(0,AO),1),LLV(LOW,2),REF(LLV(LOW,2),BARSLAST(REF(CROSS(0,AC),1) OR REF(CROSS(0,AO),1)))),IF(REF(CROSS(AC,0) OR REF(CROSS(AO,0),1),1),HHV(HIGH,2),REF(HHV(HIGH,2),BARSLAST(REF(CROSS(AC,0),1) OR REF(CROSS(AO,0),1)))));
DRAWICON(JDU1 OR BARSLAST(JDU1)<BARSLAST(JUD1),CLOSE,10),ALIGN4;
DRAWICON(JUD1 OR BARSLAST(JDU1)>BARSLAST(JUD1),CLOSE,11),ALIGN5;

混沌理论之鳄鱼线简介
⊙鳄鱼线是做什么用的？
    基本上，无论实时价格往任何方向移动，鳄鱼线扮演着使我们的交易保持正


当方向的罗盘角色。而且，鳄鱼线会协助我们在有方向的趋势中获利。并且将这

个获利持续到会吃掉我们利润的盘整趋势出现为止。
⊙鳄鱼线是如何构成的？
    鳄鱼线由三部分构成：
动量监视器：一个与市场结合并接近市场的动量监视器(动能指标AO)。
交易的指针：一个简单且仅在现在的趋势中交易的指针(碎形Fractal)。
保护的装备：一个使你在盘整走势中不会损失的保护装备。
    鳄鱼线是结合了不规则碎形几何学和非线性动力学的平均线。有蓝、红、绿

三条。
蓝线，是鳄鱼的颚。
它的画法是取13根bar的平滑移动平均，然后将算出来的结果往未来的方向移动8

根bar。
红线，是鳄鱼的牙齿。
红色线是取8根bar的平滑移动平均，然后将算出来的结果往未来的方向移动5根

bar所构成。
绿线，是鳄鱼的上唇。
绿色线是取5-bar 平滑移动平均数，然后将算出来的结果往未来的方向移动3根

bar所构成。
⊙鳄鱼线的交易策略？
    当蓝、红、绿三条移动平均线纠缠在一起时，表示鳄鱼他睡着了。当他从长

时间的睡眠中醒来时，会十分饥饿。而且进一步的追捕价格，以填满他的胃，直

到他得到满足。然后，他开始闭上嘴巴，并且丧失了进食的兴趣。只要嘴巴开始

闭起来，就是告诉我们：取得利润。并等待。观察鳄鱼是否将打个盹儿？所以，

当鳄鱼睡觉时，我们通常会逗留在市场外，并且等待。直到有个碎形（Fractal

）在下颚外被触发为止。他能让我们远离波动不定的市场，并使我们能进入重要

且趋势明显的市场中。亦即价格向上或向下突破碎形（Fractal）时，便是你从

趋势中开始获利的时候。
⊙我们的交易策略是：
﹡不进行交易，直到第一个在鳄鱼嘴巴外面的碎形（详章二：Fractal）被突破

时。
﹡若价格在鳄鱼的嘴巴之上，仅取用买的讯号而且不卖。并且将停利单向上移动

。
﹡若价格在鳄嘴向下的另一边，只取用卖的讯号。且仅在停损离场时才买。不做

多。
亦即：向上的嘴巴我们只做多。而向下的嘴巴我们只做空。
如果目前的价格正在鳄鱼嘴巴的外面，表示我们正处于某种程度的冲击波中。
如果目前的价格正环绕着鳄嘴，那我们正处于某种程度的修正波中。

上面介绍了如何使用鳄鱼来敏锐地进、出。以减少因行情波动所带来的惊吓。由

于股票及期货市场的价格产生变动，全是因为交易者对新进入的市场信息反应的

结果（混沌现象）。所以，若没有新的信息（混沌）进来，那平均线就是市场所

在。而市场将停止。
我们的工作便是：查出这些新进信息的特征，并使用在交易上使我们获利。
现在，你应已彻底地了解鳄鱼线的作用。
你也应已了解：当鳄鱼睡觉时，及饥饿中该如何做决定。


既然大家都知道鳄鱼线是由均线理论协助完成的
则这些红蓝绿线的方向就十分重要了

各位可以见到AR兄的图当中由1339.20往上后
第一次出现绿色的K线
绝对不是出场点
使用训练模式移到这一天观察一下红蓝绿线的未来几天走势
可以发现明显的多头趋势
但是为了避免看错
在出现绿色K线当天
将当天K线画出上下箱型
看隔天如何走
结果第二天直接跳空上去

由于期货是没有成交量的
而以K线为观察重心
则这个跳空前就确认翻绿的K线不过是短线回档作加码用的

回到鳄鱼线
用线控盘
收盘没有跌破绿线也就没有出场点
所以这套理论很活的
难怪雅马逊书店关于浑沌的书上百本（太多分支理论了）

使用这套想法也可以用在各个指标上面
比如说KD进入80以上当天是否止涨
划箱型观察即可

(鳄鱼线+碎型+AC+AO)